As well as including the correct register definitions, there are a few hardware changes that you need to account for:-
- Different Config options.
- File Registers start at address 32, not 7.
- Weak pullup enable is bit 7 in the Option Register, not bit 6.
- You must Call the last program address (0x3ff) to get the OSCAL value.
- Analog inputs and the comparator are enabled on startup, you must disable them to use digital I/O.
Here's some sample code that accomodates both chips:-
ifdef __12C509
PROCESSOR PIC12C509
INCLUDE <P12C509.inc>
__CONFIG _MCLRE_OFF&_CP_OFF&_WDT_ON&_IntRC_OSC
endif
ifdef __12F675
PROCESSOR PIC12F675
INCLUDE <P12F675.inc>
__CONFIG _MCLRE_OFF&_CP_OFF&_WDT_ON&_BODEN_ON&_INTRC_OSC_NOCLKOUT
endif
radix dec ; decimal numbering
ifdef __12C509
CBLOCK 7
else
CBLOCK 32 ; user RAM starts here
endif
MyVar1 ; 1st RAM location
MyVar2 ; 2nd "" ""
ENDC
;--------------------------------------------------------------------------
; Bits to be set with the OPTION instruction
;--------------------------------------------------------------------------
; bit function state
;------ ------------------------- --------------
; 7 Weak Pullups (12F6xx) 1=inactive
; 6 Weak Pullups (12C50x) 1=inactive
; 5 Tmr0 clock source 0=internal
; 4 Tmr0 clock edge 0=low->high
; 3 Prescaler assign 0=timer
; 2 }
; 1 }prescaler divide 111=1:256
; 0 }
; 76543210
#DEFINE OptionBits B'11000111'
;---------------------------------------------------------------------------
; I/O directions
;---------------------------------------------------------------------------
; 543210
#DEFINE TrisBits b'000100' ; '0' = output
ORG 0
; get oscillator calibration value and use it to fine-tune clock frequency.
; 12C508/9 has value in W at startup, 12F629/75 gets it from RETLW at 0x3ff.
ifdef __12C509
ifdef OSC_CAL
movlw OSC_CAL
endif
movwf OSCCAL ; set oscillator calibration value
else
bsf STATUS,RP0 ; register bank 1
call 0x3ff ; get OSCCAL value
movwf OSCCAL ; set oscillator calibration
bcf STATUS, RP0 ; register bank 0
endif
ifdef __12C509
clrwdt
movlw OptionBits
OPTION
else
clrwdt
bsf STATUS,RP0 ; register bank 1
movlw OptionBits
movwf OPTION_REG
bcf STATUS,RP0 ; register bank 0
clrwdt
endif
; initialise I/O registers
ifdef __12C509
clrf GPIO ; all outputs low
movlw TrisBits
TRIS GPIO ; set I/O pin directions
else
clrf GPIO ; all outputs low
bsf STATUS,RP0 ; register bank 1
movlw TrisBits
movwf TRISIO ; set I/O pin directions
ifdef ANSEL
clrf ANSEL ; disable analog inputs
endif
bcf STATUS,RP0 ; register bank 0
movlw b'00000111'
movwf CMCON ; Comparator off
endif
; CPU specific stuff done, now we can start the main program!
goto Main